furthre config on laptop

system/gpu/intel/default.nix

@@ -0,0 +1,91 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  imports = [
+  ];
+
+  options.hardware.intelgpu = {
+    driver = lib.mkOption {
+      description = "Intel GPU driver to use";
+      type = lib.types.enum [
+        "i915"
+        "xe"
+      ];
+      default = "i915";
+    };
+
+    loadInInitrd =
+      lib.mkEnableOption "Load the Intel GPU kernel module at stage 1 boot. (Added to `boot.initrd.kernelModules`)"
+      // {
+        default = true;
+      };
+
+    vaapiDriver = lib.mkOption {
+      description = "Intel VAAPI driver to use (use null to use both)";
+      type = lib.types.nullOr (
+        lib.types.enum [
+          "intel-vaapi-driver"
+          "intel-media-driver"
+        ]
+      );
+      default = null; # Use both drivers when we don't know which one to use
+    };
+
+    enableHybridCodec = lib.mkEnableOption "hybrid codec support for Intel GPUs";
+  };
+
+  config =
+    let
+      cfg = config.hardware.intelgpu;
+
+      useIntelVaapiDriver = cfg.vaapiDriver == "intel-vaapi-driver" || cfg.vaapiDriver == null;
+      intel-vaapi-driver = (pkgs.intel-vaapi-driver or pkgs.vaapiIntel).override {
+        enableHybridCodec = cfg.enableHybridCodec;
+      };
+      intel-vaapi-driver-32 =
+        (pkgs.driversi686Linux.intel-vaapi-driver or pkgs.driversi686Linux.vaapiIntel).override
+          {
+            enableHybridCodec = cfg.enableHybridCodec;
+          };
+
+      useIntelOcl =
+        useIntelVaapiDriver
+        && (config.hardware.enableAllFirmware or config.nixpkgs.config.allowUnfree or false);
+      intel-ocl = pkgs.intel-ocl;
+
+      useIntelMediaDriver = cfg.vaapiDriver == "intel-media-driver" || cfg.vaapiDriver == null;
+      intel-media-driver = pkgs.intel-media-driver;
+      intel-media-driver-32 = pkgs.driversi686Linux.intel-media-driver;
+      intel-compute-runtime = pkgs.intel-compute-runtime;
+      vpl-gpu-rt = pkgs.vpl-gpu-rt or pkgs.onevpl-intel-gpu;
+    in
+    {
+      boot.initrd.kernelModules = lib.optionals cfg.loadInInitrd [ cfg.driver ];
+
+      hardware.graphics.extraPackages =
+        lib.optionals useIntelVaapiDriver [ intel-vaapi-driver ]
+        ++ lib.optionals useIntelOcl [ intel-ocl ]
+        ++ lib.optionals useIntelMediaDriver [
+          intel-media-driver
+          intel-compute-runtime
+          vpl-gpu-rt
+        ];
+
+      hardware.graphics.extraPackages32 =
+        lib.optionals useIntelVaapiDriver [ intel-vaapi-driver-32 ]
+        ++ lib.optionals useIntelMediaDriver [ intel-media-driver-32 ];
+
+      assertions = [
+        {
+          assertion = (
+            cfg.driver != "xe" || lib.versionAtLeast config.boot.kernelPackages.kernel.version "6.8"
+          );
+          message = "Intel Xe GPU driver is not supported on kernels earlier than 6.8. Update or use the i915 driver.";
+        }
+      ];
+    };
+}

system/gpu/nvidia/default.nix

@@ -0,0 +1,6 @@
+{ lib, ... }:
+
+{
+  imports = [];
+  services.xserver.videoDrivers = lib.mkDefault [ "modesetting" "nvidia"];
+}

system/gpu/nvidia/disable.nix

@@ -0,0 +1,31 @@
+{ ... }:
+
+{
+  # This runs only intel/amdgpu igpus and nvidia dgpus do not drain power.
+
+  ##### disable nvidia, very nice battery life.
+  boot.extraModprobeConfig = ''
+    blacklist nouveau
+    options nouveau modeset=0
+  '';
+
+  services.udev.extraRules = ''
+    # Remove NVIDIA USB xHCI Host Controller devices, if present
+    ACTION=="add", SUBSYSTEM=="pci", ATTR{vendor}=="0x10de", ATTR{class}=="0x0c0330", ATTR{power/control}="auto", ATTR{remove}="1"
+
+    # Remove NVIDIA USB Type-C UCSI devices, if present
+    ACTION=="add", SUBSYSTEM=="pci", ATTR{vendor}=="0x10de", ATTR{class}=="0x0c8000", ATTR{power/control}="auto", ATTR{remove}="1"
+
+    # Remove NVIDIA Audio devices, if present
+    ACTION=="add", SUBSYSTEM=="pci", ATTR{vendor}=="0x10de", ATTR{class}=="0x040300", ATTR{power/control}="auto", ATTR{remove}="1"
+
+    # Remove NVIDIA VGA/3D controller devices
+    ACTION=="add", SUBSYSTEM=="pci", ATTR{vendor}=="0x10de", ATTR{class}=="0x03[0-9]*", ATTR{power/control}="auto", ATTR{remove}="1"
+  '';
+  boot.blacklistedKernelModules = [
+    "nouveau"
+    "nvidia"
+    "nvidia_drm"
+    "nvidia_modeset"
+  ];
+}

system/gpu/nvidia/prime.nix

@@ -0,0 +1,37 @@
+{ lib, config, ... }:
+
+{
+  imports = [ ./. ];
+
+  options = {
+    hardware.nvidia.primeBatterySaverSpecialisation = lib.mkEnableOption "configure a specialisation which turns on NVIDIA Prime battery saver";
+  };
+
+  config = {
+
+    hardware.nvidia.prime = {
+      offload = {
+        enable = lib.mkOverride 990 true;
+        enableOffloadCmd = lib.mkIf config.hardware.nvidia.prime.offload.enable true; # Provides `nvidia-offload` command.
+      };
+      # Hardware should specify the bus ID for intel/nvidia devices
+    };
+
+    specialisation = lib.mkIf config.hardware.nvidia.primeBatterySaverSpecialisation {
+      battery-saver.configuration = {
+        system.nixos.tags = [ "battery-saver" ];
+        imports = [
+          # Leave only the integrated GPU enabled
+          ./disable.nix
+        ];
+        hardware.nvidia = {
+          prime.offload.enable = lib.mkForce false;
+          powerManagement = {
+            enable = lib.mkForce false;
+            finegrained = lib.mkForce false;
+          };
+        };
+      };
+    };
+  };
+}

system/gpu/nvidia/turing/default.nix

@@ -0,0 +1,10 @@
+{ lib, config, ... }:
+let
+  nvidiaPackage = config.hardware.nvidia.package;
+in
+{
+  imports = [ ../. ];
+
+  # enable the open source drivers if the package supports it
+  hardware.nvidia.open = lib.mkOverride 990 (nvidiaPackage ? open && nvidiaPackage ? firmware);
+}